Cara Mencari Alamat Perangkat I2C Yang Tersambung Pada Arduino

mili Ampere
26 Januari 2020 11:46

869

0Kamu harus login untuk menyukai postingan ini

Kita sering menggunakan berbagai perangkat yang menggunakan komunikasi I2C dengan arduino. Baik merupakan perangkat tampilan maupun sensor. I2C memang punya peranan yang penting untuk komunikai antar IC.

Salah satu kelebihan penggunaan I2C adalah bisa menghemat kabel lumayan banyak. Jika perangkat tampilan seperti LCD yang tadinya sampai 8 kabel bisa jadi 4 kabel saja. Salah satu kelebihan lain jika diterapkan pada sensor maka sensor I2C sudah bisa mengeluarkan data digital yang sudah siap pakai untuk kemudian ditampilkan maupun untuk kontrol perangkat lain.

Jika kamu sering menggunakan sensor analog, maka pasti kamu akan seneng mendapatkan sensor yang sudah digital dan bisa dibaca cukup menggunakan I2C saja. Biasanya sensor yang seperti ini datanya lebih stabil karena pengkondisian sinyal yang sudah built in di sensor lebih bagus daripada kiat buat sendiri 🙂

Nah, sebuah arduino sendiri bisa tersambung dengan banyak perangkat I2C sekaligus menggunakan kabel yang sama. Betul kita bisa gunakan banyak tampilan dan banyak sensor yang tersambung ke sebuah arduino hanya dari SDA dan SCL saja. Ini juga merupakan salah satu kelebihan lainnya.

Dikarenakana banyak perangkat yang tersambung ke arduino hanya melalui 2 kabel yang sama, maka agar arduino bisa berkomunikasi ke sebuah perangkat dan tidak tertukar ke perangkat lain I2C memerlukan alamat yang berbeda antar satu perangkat dan perangkat yang lain. Jadi meskipun sebuah arduino tersambung ke banyak perangkat I2C pada kabel yang sama namun alamat mereka berbeda agar bisa tetap berjalan.

Jadi bagaimana cari mencari alamatnya?

Nah untuk mencari alamatnya, di kalangan komunitas penggemar arduino telah beredar sebuah source code yang bisa menscan atau mencari setiap alamat perangkat yang tersambung pada arduino. Coba code berikut pada arduino kamu.

 // --------------------------------------
// i2c_scanner
//
// Version 1
//    This program (or code that looks like it)
//    can be found in many places.
//    For example on the Arduino.cc forum.
//    The original author is not know.
// Version 2, Juni 2012, Using Arduino 1.0.1
//     Adapted to be as simple as possible by Arduino.cc user Krodal
// Version 3, Feb 26  2013
//    V3 by louarnold
// Version 4, March 3, 2013, Using Arduino 1.0.3
//    by Arduino.cc user Krodal.
//    Changes by louarnold removed.
//    Scanning addresses changed from 0...127 to 1...119,
//    according to the i2c scanner by Nick Gammon
//    http://www.gammon.com.au/forum/?id=10896
// Version 5, March 28, 2013
//    As version 4, but address scans now to 127.
//    A sensor seems to use address 120.
// Version 6, November 27, 2015.
//    Added waiting for the Leonardo serial communication.
// 
//
// This sketch tests the standard 7-bit addresses
// Devices with higher bit address might not be seen properly.
//

#include <Wire.h>


void setup()
{
  Wire.begin();

  Serial.begin(9600);
  while (!Serial);             // Leonardo: wait for serial monitor
  Serial.println("\nI2C Scanner");
}


void loop()
{
  byte error, address;
  int nDevices;

  Serial.println("Scanning...");

  nDevices = 0;
  for(address = 1; address < 127; address++ ) 
  {
    // The i2c_scanner uses the return value of
    // the Write.endTransmisstion to see if
    // a device did acknowledge to the address.
    Wire.beginTransmission(address);
    error = Wire.endTransmission();

    if (error == 0)
    {
      Serial.print("I2C device found at address 0x");
      if (address<16) 
        Serial.print("0");
      Serial.print(address,HEX);
      Serial.println("  !");

      nDevices++;
    }
    else if (error==4) 
    {
      Serial.print("Unknown error at address 0x");
      if (address<16) 
        Serial.print("0");
      Serial.println(address,HEX);
    }    
  }
  if (nDevices == 0)
    Serial.println("No I2C devices found\n");
  else
    Serial.println("done\n");

  delay(5000);           // wait 5 seconds for next scan
}

Setelah diupload, kemudian buka serial monitor pada arduino. Jika pemasangan kabel antara sensor dan arduino sudah benar maka akan terbaca sebuah alamat I2C. Sebagai contoh jika ditemukan perangkat pada alamat “0x27” maka di serial monitor akan tampil :

I2C device found at address 0x27

Selamat mencoba! btw jika tidak ditemukan juga alamatnya mungkin pemasangan kabel salah atau ada masalah pada perangkat i2c kamu.

Seperti biasa kalau ada pertanyaan boleh kok komentar di bawah 🙂